home *** CD-ROM | disk | FTP | other *** search
/ Macwelt 1 / Macwelt DVD 1.toast / Web-Publishing / HTML-Editoren / Alpha ƒ / Tcl / Modes / sMode.tcl < prev    next >
Encoding:
Text File  |  2001-01-26  |  63.2 KB  |  1,854 lines
  1. ## -*-Tcl-*-  (nowrap)
  2.  # ==========================================================================
  3.  #  Statistical Modes - an extension package for Alpha
  4.  # 
  5.  #  FILE: "sMode.tcl"
  6.  #                                    created: 01/15/00 {07:15:32 pm} 
  7.  #                                last update: 01/26/01 {12:29:02 pm}
  8.  #  Description: 
  9.  #                                 
  10.  #  For S (or S-Plus) syntax files, as well as the free distribution of R.
  11.  #  
  12.  #  Author: Craig Barton Upright
  13.  #  E-mail: <cupright@princeton.edu>
  14.  #    mail: Princeton University,  Department of Sociology
  15.  #          Princeton, New Jersey  08544
  16.  #     www: <http://www.princeton.edu/~cupright>
  17.  #  
  18.  # -------------------------------------------------------------------
  19.  #  
  20.  # Copyright (c) 2000-2001 Craig Barton Upright
  21.  # 
  22.  # This program is free software; you can redistribute it and/or modify
  23.  # it under the terms of the GNU General Public License as published by
  24.  # the Free Software Foundation; either version 2 of the License, or
  25.  # (at your option) any later version.
  26.  # 
  27.  # This program is distributed in the hope that it will be useful,
  28.  # but WITHOUT ANY WARRANTY; without even the implied warranty of
  29.  # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  30.  # GNU General Public License for more details.
  31.  # 
  32.  # You should have received a copy of the GNU General Public License
  33.  # along with this program; if not, write to the Free Software
  34.  # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  35.  # 
  36.  # ==========================================================================
  37.  ##
  38.  
  39. # ===========================================================================
  40. #
  41. # ◊◊◊◊ Initialization of S mode ◊◊◊◊ #
  42. # 
  43.  
  44. alpha::mode S 2.1.1 sMenu {*.s *.S *.R} {
  45.     sMenu electricReturn electricTab electricBraces
  46. } {
  47.     # We require 7.4b21 for prefs handling.
  48.     alpha::package require -loose AlphaTcl 7.4b21
  49.     addMenu sMenu "S+/R" S
  50.     set unixMode(splus) {S}
  51. } uninstall {
  52.     catch {file delete [file join $HOME Tcl Modes sMode.tcl]}
  53.     catch {file delete [file join $HOME Tcl Completions SCompletions.tcl]}
  54.     catch {file delete [file join $HOME Tcl Completions "S Tutorial.s"]}
  55. } help {
  56.     file "Statistical Modes Help"
  57. } maintainer {
  58.     "Craig Barton Upright" <cupright@princeton.edu> 
  59.     <http://www.princeton.edu/~cupright/>
  60. }
  61.  
  62. hook::register quitHook S::quitHook
  63.  
  64. proc sMenu {} {}
  65.  
  66. proc sMode.tcl {} {}
  67.  
  68. namespace eval S {}
  69.  
  70. # ===========================================================================
  71. #
  72. # ◊◊◊◊ Setting S mode variables ◊◊◊◊ #
  73. #
  74.  
  75. # Removing obsolete preferences from earlier versions.
  76.  
  77. set oldvars {
  78.     don'tRemindMe funcExpr parseExpr keywordColor eitherorColor
  79.     functionColor useMagicCharacter eitherOrs eitherOrColor sHelp
  80. }
  81.  
  82. foreach oldvar $oldvars {prefs::removeObsolete SmodeVars($oldvar)}
  83.  
  84. unset oldvar oldvars
  85.  
  86. # ===========================================================================
  87. #
  88. # Standard preferences recognized by various Alpha procs
  89. #
  90.  
  91. newPref var  leftFillColumn     {0}                     S
  92. newPref var  fillColumn         {75}                    S
  93. newPref var  prefixString       {# }                    S
  94. newPref var  wordBreak          {[-a-zA-Z0-9\._]+}      S
  95. newPref var  wordBreakPreface   {[^-a-zA-Z0-9\._]}      S
  96. newPref flag wordWrap           {0}                     S
  97.  
  98. # ===========================================================================
  99. #
  100. # Flag preferences
  101. #
  102.  
  103. newPref flag autoMark           {0}     S   {S::rebuildMenu markSFileAs}
  104.  
  105. # By default command double-click will send a command to on-line help, and
  106. # option double-click sends a command to the local S-Plus application. 
  107. # Check this box to switch these key combinations.
  108. newPref flag localHelp          {0}     S   {S::rebuildMenu sMenu}
  109.  
  110. # Check this box if your keyboard does not have a "Help" key.  This will
  111. # change some of the menu's key bindings.
  112. newPref flag noHelpKey          {0}     S   {S::rebuildMenu sMenu}
  113.  
  114. # Check this preference to use Venable and Ripley's MASS library for keyword
  115. # colorizing and completions
  116. newPref flag useMassLibrary     {1}     S   {S::colorizeS}
  117.  
  118. # Set the list of flag preferences which can be changed in the menu.
  119.  
  120. set SPrefsInMenu [list          \
  121.   "localHelp"                   \
  122.   "noHelpKey"                   \
  123.   "useMassLibrary"              \
  124.   ]
  125.  
  126. # ===========================================================================
  127. #
  128. # Variable preferences
  129. # 
  130.  
  131. # Enter additional arguments to be colorized. 
  132. newPref var addArguments        {c dimnames list plot replace} S {S::colorizeS}
  133.  
  134. # Enter additional S commands to be colorized.
  135. newPref var addCommands         {print} S   {S::colorizeS}
  136.  
  137. # Select the statistical application to be used.
  138. newPref var application         {S+}    S   {S::rebuildMenu sMenu} [list R S+]
  139.  
  140. # Command double-clicking on an S keyword will send it to this url for a
  141. # help reference page.
  142. newPref url helpUrl {http://stat.ethz.ch/R-alpha/library/base/html/}    S
  143.  
  144. # The "R Home Page" menu item will send this url to your browser.
  145. newPref url rHomePage           {http://cran.r-project.org/}    S
  146.  
  147. # Click on "Set" to find the local R application.
  148. newPref sig rSig                {}      S   {}
  149.  
  150. # The "S+ Home Page" menu item will send this url to your browser.
  151. newPref url s+HomePage          {http://www.splus.mathsoft.com/}        S
  152.  
  153. # Click on "Set" to find the local S+ application.  (As of this writing
  154. # there are no such applications for the Macintosh.)
  155. newPref sig s+Sig               {}      S   {}
  156.  
  157. # ===========================================================================
  158. #
  159. # Color preferences
  160. #
  161. # Nomenclature notes:
  162. # 
  163. # S-Plus is remarkably elegant in structure.  Commands have arguments, and
  164. # rarely does the language use the same names for both.  There are a few
  165. # exceptions, listed initially in the argument category.  
  166. #
  167.  
  168. # See the Statistical Modes Help file for an explanation of these different
  169. # categories, and lists of keywords.
  170. newPref color argumentColor     {magenta}       S   {S::colorizeS}
  171. newPref color commandColor      {blue}          S   {S::colorizeS}
  172. newPref color commentColor      {red}           S   {stringColorProc}
  173.  
  174. # Color of the magic character $.  Magic Characters will colorize any
  175. # string which follows them, up to the next empty space.
  176. newPref color magicColor        {black}         S   {S::colorizeS}
  177.  
  178. newPref color stringColor       {green}         S   {stringColorProc}
  179.  
  180. # The color of symbols such as "/", "@", etc.
  181. newPref color symbolColor       {magenta}       S   {S::colorizeS}
  182.  
  183. regModeKeywords -e {#}                  \
  184.   -c $SmodeVars(commentColor)           \
  185.   -s $SmodeVars(stringColor)  S {}
  186.  
  187. # ===========================================================================
  188. #
  189. # Flag Flip
  190. # 
  191. # Called by menu items, change the value of flag preferences.
  192. # 
  193.  
  194. proc S::flagFlip {pref} {
  195.  
  196.     global mode SmodeVars
  197.     
  198.     set SmodeVars($pref) [expr {$SmodeVars($pref) ? 0 : 1}]
  199.     set oldMode $mode
  200.     set mode "S"
  201.     synchroniseModeVar $pref $SmodeVars($pref)
  202.     set mode $oldMode
  203.     if {$SmodeVars($pref)} {
  204.         set end "on"
  205.     } else {
  206.         set end "off"
  207.     }
  208.     message "The \"$pref\" preference is now $end."
  209. }
  210.  
  211. # ===========================================================================
  212. #
  213. # Comment Character variables for Comment Line / Paragraph / Box menu items.
  214. # 
  215.  
  216. set S::commentCharacters(General)   "# "
  217. set S::commentCharacters(Paragraph) [list "## " " ##" " # "]
  218. set S::commentCharacters(Box)       [list "#" 1 "#" 1 "#" 3]
  219.  
  220. # ===========================================================================
  221. #
  222. # ◊◊◊◊ Keyword Dictionaries ◊◊◊◊ #
  223. #
  224.  
  225. # Making sure that SUserCommands and SUserArguments exist.
  226. # These will be over-ridden if they are loaded from a ${mode}Prefs.tcl file.
  227. #
  228.  
  229. set SUserCommands       ""
  230. set SUserArguments      ""
  231.  
  232. # ===========================================================================
  233. #
  234. # ◊◊◊◊   S Commands   ◊◊◊◊ #
  235. #
  236.  
  237. set SCommands {
  238.     abbreviate abline abs ace acf acf.plot adm.ave adm.filt adm.smo acos
  239.     add1 aggregate aggregrate.ts agnes akima alias all all.equal allocated
  240.     anova any aov aov.genyates aperm append apply approx ar ar.burg ar.gm
  241.     ar.yw arg.dialog args arima.diag arima.filt arima.forecast
  242.     arima.fracdiff arima.fracdiff.sim arima.mle arima.sim arima.td array
  243.     arrows as.character as.data.frame as.data.frame.array as.data.frame.ts
  244.     as.matrix as.numeric as.vector as.xxx asin assign atan attach attr
  245.     attributes avas axis backsolve banking barchart barplot BATCH bcv
  246.     binomial biplot biplot.default bootstrap boxplay browser brush bs
  247.     butterfly bwplot by c cancor cat cbind cdf.compare ceiling cex
  248.     character charmatch chissq.gof chol clara class close.screen cloud
  249.     cmdscale coef coefficients contour countourplot contr.helmert
  250.     contr.poly contr.sdif contr.sum contr.treatment contrasts cor cor.test
  251.     correlogram cos cosh count.fields cov.mve cov.wt cox.zph coxph
  252.     crossprod crosstabs cts cummax cummin cumprod cumsum cut cutree cv.tree
  253.     D daisy data.class data.dump data.frame data.matrix data.restore
  254.     database.object date dates dbwrite debugger demod density densityplot
  255.     deparse deriv deriv3 design det detach dev.ask dev.copy dev.cur
  256.     dev.list dev.next dev.off dev.prev dev.print dev.set deviance dget diag
  257.     Diagonal diana diff dim dimnames dist dmvnorm do.call dos dos.time
  258.     dotchart dotplot dput drop drop1 dummy.corf dump dump.calls dump.frames
  259.     dumpdata duplicated ed eigen equal.count Error eval exists exp
  260.     expand.grid expcov expn expression F fac/desogm faces factanal factor
  261.     family fanny fft fig file.exists filter find .First .First.lib
  262.     .First.local fitted fitted.values fix fixed.effects floor for format
  263.     formula fpl fractionate frame frequency.polygram symbol gam gam.plot
  264.     gamma gaucov gaussian get glm glm.links glm.variances graphics.off
  265.     graphsheet grep hclust help help.off help.start hist hist.FD hist.scott
  266.     hist2d histogram history hpgl hplg I() identify if ifelse Im image
  267.     inspect integrate interaction.plot interp inverse.gaussian invisible
  268.     iris4d is.characger is.na is.random is.xxx its julian Kaver keep.order
  269.     Kenvl key Kfn kmeans kruskal.test ks.gof ksmooth l1fit lag lapply .Last
  270.     last.dump .Last.value leaps legend length letters levelplot levels
  271.     lgamma library limits.bca limits.emp lines list lm lm.influence lme
  272.     lmsreg lo loadings location.m locator loess log log10 loglin lower.tri
  273.     lowess ltsreg lu mad mahalanobis mai make.call make.family make.fileds
  274.     make.groups manova mar masked mat2tr match match.arg matplot matrix
  275.     Matrix.class max mclass mclust mean median memory.size merge mex mfcol
  276.     mfrow min misclass.tree missing mkh mode model.frame.tree model.matrix
  277.     model.tables mona monthplot motif mreloc ms mstree mtext multinom
  278.     na.action na.fail na.gam.replace na.omit names nchar nclass.FD
  279.     nclass.scott ncol neg.bin next NextMethod nlme nlminb nlregb nls
  280.     nlsList nnet nnet.Hess nnls.fit norm nroff nrow ns ntrellis numeric
  281.     as.design objdiff objects offset oma omd omi on.exit openlook optimize
  282.     optimize options .Options order ordered outer output pairs pam par
  283.     partition.tree paste pdf.graph persp persp.setup perspp pi pie piechart
  284.     plclust plot.gam plot.survfit pltree pmatch pmax pmin pmvnorm pnorm
  285.     points poisson poly polygon polyroot post.tree postscript ppinit pplik
  286.     ppoints ppreg ppregion prcomp predict predict.factanal predict.gam
  287.     predict.lm predict.lme predict.tree princomp print.summary
  288.     print.trellis printgraph prmat proc.time prod profile proj prompt
  289.     prompt.screen prune.misclass prune.tree Psim pty q qda qqline qqnorm
  290.     qqplot qr qr.coef qr.fitted qr.Q qr.R qr.resid qr.X quantile quasi
  291.     .Random.seed range rank raov rbind rbiwt rcond Re read.table Recall
  292.     remove reorder.factor rep repeat replications resid residuals restart
  293.     return rev rm rmv rmvnorm rnorm rotate rotate.default round row
  294.     row.names RowPermutation Rows tpois rreg rts rug s sabl sample sapply
  295.     scale scale.a scale.tau scan scatter.smooth screen screenplot
  296.     se.contrast search segments semat seq set.seed show.settings sign
  297.     signig sin sinh sink slice.index slm smooth.spline solve solve.qr
  298.     solve.upper sort sort.list source spatial spec.ar spec.pgram spec.taper
  299.     spectrum sphercov spin spline split split.screen splom sqrt SSI stars
  300.     state.name statlib stdres stem step stepAIC stepfun stepwise stl stop
  301.     Strauss stripplot structure studres subplot subset substutute substring
  302.     sum summary summary.coxph summary.gam summary.lm supsmu surf.gls
  303.     surf.ls Surv survdiff survexp survfit survreg svd sweep switch symbols
  304.     synchronize sys.parent system t t.test table tan tanh tapply tempfile
  305.     terms text text.default title tprint trace traceback tree tree.control
  306.     trellis trellis.3d.args trellis.args trellis.device trellis.par.get
  307.     trellis.par.set trmat tue.file.name trunc ts.intersect ts.lines ts.plot
  308.     ts.points ts.union tspar ttest twoway unclass unique uniroot unix
  309.     unix.time unlink unlist unpack update usa UseMethod usr var var.test
  310.     varcomp variogram vcov.nlminb vcov.mlreg becnorm vi warning while
  311.     wilcox.text win.colorscheme win.graph win.printer win3 window wireframe
  312.     write write.table xor xyplot
  313. } 
  314.  
  315. # ===========================================================================
  316. #
  317. # ◊◊◊◊   S Arguments   ◊◊◊◊ #
  318. #
  319.  
  320. set SArguments {
  321.     add aic all angle append as.is aux axes bandwidth best border box.ratio
  322.     boxplots byrow center circles cohort col.names collapse conditional
  323.     conf.int constant cor cuts data decay degree delta demean density depth
  324.     detail detrend device df dframe differences dimmames.write dist drape
  325.     eig else end entropy erase et evaluate exclude extrap factors family
  326.     fence file fileout fill first frame frequency FUN full.precision fun
  327.     gof.lag gradient h head header height help Hess hessian highlight hist
  328.     horizontal in inches individual int inter.max intercept inverse
  329.     inverted iter jacobian jitter k kernel labels lag lims link lineout
  330.     local low lower lty lwd max max.subdiv maxit menu message method metric
  331.     more multi.line n NA na.action na.last na.rm name ndeltat new nf ng
  332.     niter noise normalize nu NULL nv offline onefile only.values orthogonal
  333.     p parameters partial pattern pivot plane plotit pos prior prob
  334.     probability probs psi.fun rang rectangles reverse rho rotation save
  335.     scale scores se.fit sep short side sim simplify skip softmax span spar
  336.     spin squares stars start subset summ symmetric taper test thermometers
  337.     ticks tol trace trim tuning twodig type upper v var.axes what where
  338.     which window wt x xl xlab xu y yl ylab yu
  339. }
  340.  
  341. # ===========================================================================
  342. #
  343. # ◊◊◊◊   S Mass Library   ◊◊◊◊ #
  344. #
  345.  
  346. set SMassLibrary {
  347.     Aids2 Boston Cars93 Choleski Cushings DDT GAGurine IQR Insurance
  348.     Melanoma OME Pima.tr Rabbit Rubber Sitka Sitka89 Skye Traffic
  349.     UScereal UScrime abbey accdeaths addterm animals anova.negbin area
  350.     austres bcv beaver1 beaver2 biopsy biplot.princomp birthwt boxcox cats
  351.     cement chem coop corresp cov.trob cpgram cpus crabs deaths digamma
  352.     drivers dropterm eqscplot faithful farms fdeaths fgl forbes fractions
  353.     galaxies gamma.dispersion gamma.shape.glm gehan genotype gilgais ginv
  354.     glm.convert glm.nb hills histplot huber hubers immer isoMDS janka kde2d
  355.     lda ldahist leuk lh loglm logtrans mammals mca mcycle mdeaths menarche
  356.     michelson minn38 motors mvrnorm negative.binomial newcomb nottem npr1
  357.     oats painters pairs.lda petrol phones plot.lda plot.mca predict.lda
  358.     predict.mca predict.qda qda quine rational rlm rms.curv rnegbin road
  359.     rock rotifer sammon ships shoes shrimp shuttle snails stdres steam
  360.     stepAIC stormer studres summary.loglm summary.negbin summary.rlm survey
  361.     synth.tr theta.md theta.mm topo trees trigamma truehist ucv vcov
  362.     vcov.nlregb waders width.SJ write.matrix wtloss
  363. }
  364.  
  365. # ===========================================================================
  366. # 
  367. # Colorize S.
  368. # 
  369. # Set all keyword lists, and colorize.
  370. # 
  371. # Could also be called in a <mode>Prefs.tcl file
  372. # 
  373.  
  374. proc S::colorizeS {{pref ""}} {
  375.     
  376.     global SmodeVars SCommands SArguments SMassLibrary 
  377.     global SUserCommands SUserArguments Scmds SCommandList
  378.     
  379.     # First setting aside only the commands, for generic completions.
  380.     set SCommandList [concat \
  381.       $SCommands $SmodeVars(addCommands) $SUserCommands]
  382.     if {$SmodeVars(useMassLibrary)} {
  383.         append SCommandList " $SMassLibrary"
  384.     }
  385.     # Then, create the list of all keywords for completions.
  386.     set Scmds [lsort [lunique [concat \
  387.       $SCommandList $SArguments $SmodeVars(addArguments) $SUserArguments \
  388.       ]]]
  389.  
  390.     # Commands
  391.     regModeKeywords -a -k $SmodeVars(commandColor) S $SCommandList 
  392.  
  393.     if {$SmodeVars(useMassLibrary)} {
  394.         regModeKeywords -a -k $SmodeVars(commandColor) S $SMassLibrary
  395.     } else {
  396.         regModeKeywords -a -k {none} S $SMassLibrary
  397.     }
  398.     # Arguments
  399.     set SArgumentColorList [concat \
  400.       $SArguments  $SmodeVars(addArguments) $SUserArguments]
  401.     regModeKeywords -a -k $SmodeVars(argumentColor) S $SArgumentColorList
  402.     
  403.     # Symbols
  404.     regModeKeywords -a                                                  \
  405.       -m {$}                                                            \
  406.       -k $SmodeVars(magicColor) S {}                                    \
  407.       -i "+" -i "-" -i "*" -i "_" -i "\\"                               \
  408.       -I $SmodeVars(symbolColor) 
  409.  
  410.     if {$pref != ""} {refresh}
  411.     if {$pref == "useMassLibrary"} {S::rebuildMenu sMenu} 
  412. }
  413.  
  414. # Call this now.
  415.  
  416. S::colorizeS
  417.  
  418. # ===========================================================================
  419. #
  420. # Reload Completions.  
  421. # 
  422. # This is now an obsolete proc.
  423. # 
  424.  
  425. proc S::reloadCompletions {} {
  426.     alertnote "\"S::reloadCompletions\" is an obsolete proc.\
  427.       It should be removed from your SPrefs.tcl file."
  428. }
  429.  
  430. # ===========================================================================
  431. #
  432. # ◊◊◊◊ Key Bindings, Electrics ◊◊◊◊ #
  433. # 
  434.  
  435. # Known bug: Key-bindings from other global menus might conflict with those
  436. # defined in the Stata menu.  This will help ensure that this doesn't happen.
  437.  
  438. Bind 's'    <cs>    {S::switchToS ""} S
  439. Bind 'p'    <cs>    {S::processFile} S
  440. Bind 'p'    <csz>   {S::processSelection} S
  441. Bind 'p'    <cs>    {S::insertPath} S
  442.  
  443. Bind 'n'    <sz>    {S::nextCommand} S
  444. Bind 'p'    <sz>    {S::prevCommand} S
  445. Bind 's'    <sz>    {S::selectCommand} S
  446. Bind 'c'    <sz>    {S::copyCommand} S
  447.  
  448. Bind 'i'    <cz>    {S::reformatCommand} S
  449.  
  450. Bind '\r'   <s>     {S::continueCommand} S
  451. Bind '\)'           {S::electricRight "\)"} S
  452.  
  453. # For those that would rather use arrow keys to navigate.  Up and down
  454. # arrow keys will advance to next/prev command, right and left will also
  455. # set the cursor to the top of the window.
  456.  
  457. Bind    up  <sz>    {S::prevCommand 0 0} S
  458. Bind  left  <sz>    {S::prevCommand 0 1} S
  459. Bind  down  <sz>    {S::nextCommand 0 0} S
  460. Bind right  <sz>    {S::nextCommand 0 1} S
  461.  
  462. # ===========================================================================
  463. # 
  464. # S Carriage Return
  465. # 
  466. # Inserts a carriage return, and indents properly.
  467. # 
  468.  
  469. proc S::carriageReturn {} {
  470.     
  471.     global SmodeVars
  472.     
  473.     if {[isSelection]} {deleteSelection} 
  474.     
  475.     set pos1 [lineStart [getPos]]
  476.     set pos2 [getPos]
  477.     if {[regexp {^([\t ])*(\}|\)|dev\.off)} [getText $pos1 $pos2]]} {
  478.         createTMark temp $pos2
  479.         catch {bind::IndentLine}
  480.         gotoTMark temp ; removeTMark temp
  481.     } 
  482.     insertText "\r"
  483.     catch {bind::IndentLine}
  484. }
  485.  
  486. # ===========================================================================
  487. #
  488. # Electric Left, Right
  489. # 
  490. # Adapted from "tclMode.tcl"
  491. # 
  492.  
  493. proc S::electricLeft {} {
  494.  
  495.     if {[literalChar]} {
  496.         typeText "\{"
  497.         return
  498.     }
  499.     set pat "\}\[ \t\r\n\]*(else(if)?)\[ \t\r\n\]*\$"
  500.     set pos [getPos]
  501.     if { [set result [findPatJustBefore "\}" $pat $pos word]] == "" } { 
  502.         insertText "\{"
  503.         return
  504.     }
  505.     # we have an if/else(if)/else
  506.     switch -- $word {
  507.         "else" {
  508.             deleteText [lindex $result 0] $pos
  509.             elec::Insertion "\} $word \{\r\t••\r\}\r••"
  510.         }
  511.         "elseif" {
  512.             deleteText [lindex $result 0] $pos
  513.             elec::Insertion "\} $word \{••\} \{\r\t••\r\}\r••"
  514.         }
  515.     }
  516. }
  517.     
  518. proc S::electricRight {{char "\}"}} {
  519.     
  520.     if {[literalChar]} {
  521.         typeText $char
  522.         return
  523.     }
  524.     set pos [getPos]
  525.     typeText $char
  526.     if {![regexp {[^ \t]} [getText [lineStart $pos] $pos]]} {
  527.         set pos [lineStart $pos]
  528.         createTMark temp [getPos]
  529.         catch {bind::IndentLine}
  530.         gotoTMark temp ; removeTMark temp
  531.         bind::CarriageReturn
  532.     } 
  533.     if {[catch {blink [matchIt $char [pos::math $pos - 1]]}]} {
  534.         beep ; message "No matching $char !!"
  535.     } 
  536. }
  537.  
  538. # ===========================================================================
  539. #
  540. # Continue Command
  541. # 
  542. # Over-rides the automatic indentation of lines that begin with \} or \)
  543. # so that additional text can be entered.
  544. # 
  545.  
  546. proc S::continueCommand {} {
  547.  
  548.     global indent_amounts
  549.     
  550.     bind::CarriageReturn
  551.     if {[pos::compare [getPos] != [maxPos]]} {
  552.         set nextChar [getText [getPos] [pos::math [getPos] + 1]]
  553.         if {$nextChar == "\}" || $nextChar == "\)"} {
  554.             insertText [text::indentOf $indent_amounts(2)]
  555.         } 
  556.     } 
  557. }
  558.  
  559. # ===========================================================================
  560. #
  561. # ◊◊◊◊ Indentation ◊◊◊◊ #
  562. # 
  563. # S::correctIndentation is necessary for Smart Paste, and returns the
  564. # correct level of indentation for the current line.  S::indentLine uses
  565. # this level to indent the current line.
  566. # 
  567. # In S::correctIndentation, we grab the previous non-commented line, remove
  568. # all of the characters besides braces, quotes, and hashmarks, and then
  569. # convert it all to a list to be evaluated.  Braces and hashmarks contained
  570. # within quotes, as well as literal characters, should all be ignored and
  571. # the remaining braces are used to determine the correct level of nesting.
  572. # 
  573.  
  574. proc S::indentLine {{pos ""}} {
  575.     
  576.     if {$pos == ""} {set pos [getPos]} 
  577.     # Get details of current line.
  578.     set posBeg [lineStart [getPos]]
  579.     set text [getText $posBeg [nextLineStart $posBeg]]
  580.     regexp {^[ \t]*} $text white
  581.     set posNext1 [pos::math $posBeg + [string length $white]]
  582.     set posNext2 [pos::math $posNext1 + 1]
  583.     if {[pos::compare $posNext2 > [maxPos]]} {
  584.         set posNext2 [maxPos]
  585.     } 
  586.     # Determine the correct level of indentation for this line, given the
  587.     # next character.
  588.     set lwhite [S::correctIndentation $pos [getText $posNext1 $posNext2]]
  589.     set lwhite [text::indentOf $lwhite]
  590.     if {$white != $lwhite} {
  591.         replaceText $posBeg $posNext1 $lwhite
  592.     }
  593.     goto [pos::math $posBeg + [string length $lwhite]]
  594. }
  595.  
  596. proc S::correctIndentation {pos {next ""}} {
  597.     
  598.     global indent_amounts SmodeVars
  599.     
  600.     set posBeg   [lineStart $pos]
  601.     # Get information about this line, previous line ...
  602.     set thisLine  [S::getCommandLine $posBeg 1 1]
  603.     set prevLine1 [S::getCommandLine [pos::math $posBeg - 1] 0 1]
  604.     set prevLine2 [S::getCommandLine [pos::math [lindex $prevLine1 0] - 1] 0 1]
  605.     set lwhite    [lindex $prevLine1 1]
  606.     # If we have a previous line ...
  607.     if {[pos::compare [lindex $prevLine1 0] != $posBeg]} {
  608.         # Indent if the preceding command was a postscript command.
  609.         set pL1 [string trim [lindex $prevLine1 2]]
  610.         if {[regexp {^[\t ]*postscript([\t ]*\()} $pL1]} {
  611.             incr lwhite $indent_amounts(2)
  612.         } 
  613.         # Indent if the last line did not terminate the command.
  614.         if {[string trimright $pL1 "\\"] != $pL1} {
  615.             incr lwhite $indent_amounts(1)
  616.         } 
  617.         # Check to make sure that the previous command was not itself a
  618.         # continuation of the line before it.
  619.         if {[pos::compare [lindex $prevLine2 0] != [lindex $prevLine1 0]]} {
  620.             set pL2 [string trim [lindex $prevLine2 2]]
  621.             if {[string trimright $pL2 "\\"] != $pL2} {
  622.                 incr lwhite $indent_amounts(-1)
  623.             } 
  624.         } 
  625.         # Find out if there are any unbalanced {,},(,) in the last line.
  626.         regsub -all {[^ \{\}\(\)\"\#\\]} $pL1 { } line
  627.         # Remove all literals.
  628.         regsub -all {\\\{|\\\}|\\\(|\\\)|\\\"|\\\#} $line { } line
  629.         regsub -all {\\} $line { } line
  630.         # Remove everything surrounded by quotes.
  631.         regsub -all {\"([^\"]+)\"} $line { } line
  632.         regsub -all {\"} $line { } line
  633.         # Remove all characters following the first valid comment.
  634.         if {[regexp {\#} $line]} {
  635.             set line [string range $line 0 [string first {#} $line]]
  636.         } 
  637.         # Now turn all braces into 2's and -2's
  638.         regsub -all {\{|\(} $line { 2 }  line
  639.         regsub -all {\}|\)} $line { -2 } line
  640.         # This list should now only contain 2's and -2's.
  641.         foreach i $line {
  642.             if {$i == "2" || $i == "-2"} {incr lwhite $indent_amounts($i)} 
  643.         }
  644.         # Did the last line start with a lone \) or \} ?  If so, we want to
  645.         # keep the indent, and not make call it an unbalanced line.
  646.         if {[regexp {^[\t ]*(\}|\))} $pL1]} {
  647.             incr lwhite $indent_amounts(2)
  648.         } 
  649.     } 
  650.     # If we have a current line ...
  651.     if {[pos::compare [lindex $thisLine 0] == $posBeg]} {
  652.         # Reduce the indent if the first non-whitespace character of this
  653.         # line is ) or \}.
  654.         set tL [lindex $thisLine 2]
  655.         if {$next == "\}" || $next == ")" || [regexp {^[\t ]*(\}|\)|dev\.off)} $tL]} {
  656.             incr lwhite $indent_amounts(-2)
  657.         } 
  658.     } 
  659.     # Now we return the level to the calling proc.
  660.     return [expr {$lwhite > 0 ? $lwhite : 0}]
  661. }
  662.  
  663. # ===========================================================================
  664. # 
  665. # Get Command Line
  666. # 
  667. # Find the next/prev command line relative to a given position, and return
  668. # the position in which it starts, its indentation, and the complete text
  669. # of the command line.  If the search for the next/prev command fails,
  670. # return an indentation level of 0.
  671. # 
  672.  
  673. proc S::getCommandLine {pos {direction 1} {ignoreComments 1}} {
  674.     
  675.     if {$ignoreComments} {
  676.         set pat {^[\t ]*[^\t\r\n\# ]}
  677.     } else {
  678.         set pat {^[\t ]*[^\t\r\n ]}
  679.     } 
  680.     set posBeg [pos::math [lineStart $pos] - 1]
  681.     if {[pos::compare $posBeg < [minPos]]} {
  682.         set posBeg [minPos]
  683.     } 
  684.     set lwhite 0
  685.     if {![catch {search -f $direction -r 1 $pat $pos} match]} {
  686.         set posBeg [lindex $match 0]
  687.         set lwhite [posX [pos::math [lindex $match 1] - 1]]
  688.     }
  689.     set posEnd [pos::math [nextLineStart $posBeg] - 1]
  690.     if {[pos::compare $posEnd > [maxPos]]} {
  691.         set posEnd [maxPos]
  692.     } 
  693.     return [list $posBeg $lwhite [getText $posBeg $posEnd]]
  694. }
  695.  
  696. # ===========================================================================
  697. # 
  698. # ◊◊◊◊ Command Double Click ◊◊◊◊ #
  699. #
  700. # Checks to see if the highlighted word appears in any keyword list, and if
  701. # so, sends the selected word to the www.mathsoft.com help site.
  702. # 
  703. # (The above is not yet implemented -- where's a S help site ???)
  704. #
  705. # Control-Command double click will insert syntax information in status bar.
  706. # Shift-Command double click will insert commented syntax information in window.
  707. # 
  708. # (The above is not yet implemented -- need to enter all of the syntax info.)
  709. # 
  710.  
  711. proc S::DblClick {from to shift option control} {
  712.     
  713.     # First make sure that Scmds has been defined.
  714.     
  715.     SCompletions.tcl
  716.     
  717.     global SmodeVars Scmds SSyntaxMessage
  718.         
  719.     set where [getPos]
  720.     
  721.     select $from $to
  722.     set command [getSelect]
  723.     
  724.     set varDef "$command+\[\t \]+(<\-|_)"
  725.     
  726.     if {![catch {search -s -f 1 -r 1 -m 0 $varDef [minPos]} match]} {
  727.         # First check current file for a variable (etc) definition, and if
  728.         # found ...
  729.         placeBookmark
  730.         goto [lineStart [lindex $match 0]]
  731.         message "press <Ctl .> to return to original cursor position"
  732.         return
  733.         # Could next check any open windows, or files in the current
  734.         # window's folder ...  but not implemented.  For now, variables
  735.         # (etc) need to be defined in current file.
  736.     } elseif {[lsearch -exact $Scmds $command] == -1} {
  737.         message "\"$command\" is not defined as an S system keyword."
  738.         return
  739.     }
  740.     # Defined as a keyword, determine if there's a syntax message.
  741.     # Any modifiers pressed?
  742.     if {$control} {
  743.         # CONTROL -- Just put syntax message in status bar window
  744.         if {[info exists SSyntaxMessage($command)]} {
  745.             message "$SSyntaxMessage($command)"        
  746.         } else {
  747.             message "Sorry, no syntax information available for $command"
  748.         } 
  749.     } elseif {$shift} {
  750.         # SHIFT --Just insert syntax message as commented text
  751.         if {[info exists SSyntaxMessage($command)]} {
  752.             endOfLine
  753.             insertText "\r"
  754.             insertText "$SSyntaxMessage($command)"
  755.             comment::Line
  756.         } else {
  757.             message "Sorry, no syntax information available for $command"
  758.         }
  759.     } elseif {$option && !$SmodeVars(localHelp)} {
  760.         # Now we have four possibilities, based on "option" key and the
  761.         # preference for "local Help".
  762.         # 
  763.         # OPTION, local help isn't checked -- Send command to local application
  764.         S::localCommandHelp $command
  765.     } elseif {$option && $SmodeVars(localHelp)} {
  766.         # OPTION, but local help is checked -- Send command for on-line help.
  767.         S::wwwCommandHelp $command
  768.     } elseif {$SmodeVars(localHelp)} {
  769.         # No modifiers, local help is checked -- Send command to local app.
  770.         S::localCommandHelp $command
  771.     } else {
  772.         # No modifiers, no local help checked -- Send command for on-line
  773.         # help.  This is the "default" behavior.
  774.         S::wwwCommandHelp $command
  775.     }
  776. }
  777.  
  778. # ===========================================================================
  779. # 
  780. # WWW Command Help
  781. # 
  782. # Send command to defined url, prompting for text if necessary.
  783. # 
  784.  
  785. proc S::wwwCommandHelp {{command ""}} {
  786.     
  787.     global SmodeVars
  788.     
  789.     if {$command == ""} {
  790.         set command [prompt "on-line S+/R help for ... " [getSelect]] 
  791.         # set command [statusPrompt "on-line help for ... " ] 
  792.     } 
  793.     message "\"$command\" sent to $SmodeVars(helpUrl)"
  794.     icURL $SmodeVars(helpUrl)${command}.html
  795. }
  796.  
  797. # ===========================================================================
  798. # 
  799. # Local Command Help
  800. # 
  801. # Find a local help file, and open it in a browser.
  802. # Prompt for text if necessary.
  803. # 
  804. # We're assuming that the help does exist as a file somewhere, as opposed
  805. # to being an internal application help function.  At the moment, we also
  806. # assume that this file is html, although that could be a mode option as
  807. # well.
  808. # 
  809. # This needs more work ...
  810. # 
  811.  
  812. proc S::localCommandHelp {{command ""}} {
  813.     
  814.     global SmodeVars
  815.     
  816.     set app $SmodeVars(application)
  817.  
  818.     if {$command == ""} {
  819.         set command [prompt "local $app application help for ... " [getSelect]] 
  820.         # set command [statusPrompt "local S application help for ... " ] 
  821.     } 
  822.     S::processSelection "help ($command)" "$app"
  823. }
  824.  
  825. # proc S::localCommandHelp {{command ""} {app ""}} {
  826. #     
  827. #     global SmodeVars tcl_platform
  828. #     
  829. #     if {$app == ""} {
  830. #         set app $SmodeVars(application)
  831. #     } 
  832. #     if {$command == ""} {
  833. #         set command [prompt "local $app application help for ... " [getSelect]]
  834. #         # set command [statusPrompt "local S-Plus application help for ..." ]
  835. #     }
  836. #     set pf $tcl_platform(platform)
  837. #     
  838. #     # We have six possible options here, based on platform and application.
  839. #     # For each option, we want to create the path to the help file.
  840. #     
  841. #     if {$pf == "macintosh"} {
  842. #         # We'll kill this right now.  The rest is for future code ...
  843. #         S::betaMessage 
  844. #         # Make sure that the Macintosh application for the signature exists.
  845. #         if {[catch {[nameFromAppl [S::sig $app]]}]} {
  846. #             S::setApplication $app
  847. #         } 
  848. #         if {$SmodeVars(application) == "R"} {
  849. #             # Macintosh, R
  850. #         } else {
  851. #             # Macintosh, S+
  852. #         }
  853. #     } elseif {$pf == "windows" || $pf == "unix"} {
  854. #         # Make sure that the Windows application for the signature exists. 
  855. #         # We assume that this will work for unix, too.
  856. #         if {![file exists [S::sig $app]]} {
  857. #             S::setApplication $app
  858. #         } 
  859. #         if {$SmodeVars(application) == "R"} {
  860. #             # Windows, R
  861. #             set appRoot  [file dirname [file dirname [S::sig]]]
  862. #             set helpLib  [file join $appRoot library base html]
  863. #             set helpFile [file join $helpLib ${command}.html]
  864. #         } else {
  865. #             # Windows, S+
  866. #             S::betaMessage
  867. #         }
  868. #     }
  869. #     # Now we look for the actual help file.
  870. #     if {![file exists $helpFile]} {
  871. #         beep ; message "Sorry, no help file for \"$command\" was found."
  872. #         error "No help file found for \"$command\"."
  873. #     } else {
  874. #         help::openFile $helpFile 
  875. #     } 
  876. # }
  877.  
  878.  
  879. # ===========================================================================
  880. #
  881. # ◊◊◊◊ Mark File and Parse Functions ◊◊◊◊ #
  882. #
  883.  
  884. # ===========================================================================
  885. #
  886. # S Mark File
  887. # 
  888. # This will return the first 35 characters from the first non-commented
  889. # word that appears in column 0.  All other output files (those not
  890. # recognized) will take into account the additional left margin elements
  891. # added by S+/R.
  892. #
  893.  
  894. proc S::MarkFile {{type ""}} {
  895.     
  896.     removeAllMarks
  897.     
  898.     message "Marking File …"
  899.     
  900.     set pos [minPos]
  901.     set count 0
  902.     # Figure out what type of file this is -- source, or output.
  903.     # The variable "type" refers to a call from the S menu.
  904.     # Otherwise we try to figure out the type based on the file's suffix.
  905.     if {$type == ""} {
  906.         if {[win::CurrentTail] == "* S Mode Example *"} {
  907.             # Special case for Mode Examples, but only if called from
  908.             # Marks menu.  (Called from S menu, "type" will over-ride.)
  909.             set type  ".s"
  910.         } else {
  911.             set type [file extension [win::CurrentTail]]
  912.         }
  913.     }
  914.     # Now set the mark regexp.
  915.     if {$type == ".s" } {
  916.         # Source file.
  917.         set markExpr {^(###[ ]|####[ ])?[-a-zA-Z0-9]}
  918.     } else {
  919.         # None of the above, so assume that it's output
  920.         set markExpr {^(> )+(###[ ]|####[ ])?[-a-zA-Z0-9]}
  921.     }
  922.     # Mark the file
  923.     while {![catch {search -s -f 1 -r 1 -m 0 -i 1 $markExpr $pos} match]} {
  924.         incr count
  925.         set posBeg [lindex $match 0]
  926.         set posEnd [nextLineStart $posBeg]
  927.         if {[pos::compare $posEnd > [maxPos]]} {set posEnd [maxPos]} 
  928.         set line   [string trimright [getText $posBeg $posEnd]]
  929.         # Get rid of the leading "> " for output files.
  930.         regsub {^ >} $line {} line
  931.         # Get rid of braces.
  932.         regsub -all {\{|\[} $line {(} line
  933.         regsub -all {\}|\]} $line {)} line
  934.         set line  "  $line"
  935.         if {[regsub {  #### } $line {* } line]} {
  936.             incr count -1
  937.         } elseif {[regsub {  ### } $line {• } line]} {
  938.             incr count -1
  939.         } 
  940.         if {[string length $line] > 35} {
  941.             set line "[string range $line 0 35] ..."
  942.         } 
  943.         setNamedMark $line $posBeg $posBeg $posBeg
  944.         set pos $posEnd
  945.     }
  946.     message "This file contains $count commands."
  947. }
  948.  
  949. # ===========================================================================
  950. #
  951. # S Parse Functions
  952. # 
  953. # Borrowed from C++, with modifications.
  954. # 
  955.  
  956. proc S::parseFuncs {} {
  957.     
  958.     global sortFuncsMenu
  959.  
  960.     set funcExpr  {[A-Za-z0-9~_.]+[A-Za-z0-9~_.]+[\t ]*\(}
  961.     set parseExpr {\b([-\w_:.]+)[\t ]*\(}
  962.     
  963.     set pos [minPos]
  964.     set m {}
  965.     while {[set result [search -s -f 1 -r 1 -i 0 -n $funcExpr $pos]] != ""} {
  966.         set pos1 [lindex $result 0]
  967.         set pos2 [lindex $result 1]
  968.         regexp -- $parseExpr [getText $pos1 $pos2] match command
  969.         # Get the line that contains this command.
  970.         set commandLine [getText [lineStart $pos1] $pos2]
  971.         # Strip off anything after the first valid comment.
  972.         regsub -all {\\\#} $commandLine { } commandLine 
  973.         if {[regexp {\#} $commandLine]} {
  974.             set firstComment [string first {#} $commandLine]
  975.             set commandLine [string range $commandLine 0 $firstComment]
  976.         } 
  977.         if {[regexp $command $commandLine]} {
  978.             # The command is still in the line.
  979.             lappend m [list $command $pos1]
  980.         } 
  981.         set pos [nextLineStart $pos2]
  982.     }
  983.     if {$sortFuncsMenu} {
  984.         regsub -all "\[\{\}\]" [lsort -ignore $m] "" m
  985.     } else {
  986.         regsub -all "\[\{\}\]" $m "" m
  987.     }   
  988.     return $m
  989. }
  990.  
  991. # ===========================================================================
  992. # 
  993. # ◊◊◊◊ -------------------- ◊◊◊◊ #
  994. # 
  995. # ◊◊◊◊ S Menu ◊◊◊◊ #
  996. # 
  997. # based upon the Stata menu, contributed by 
  998. # L. Phillip Schumm <pschumm@uchicago.edu>
  999. # 
  1000.  
  1001. proc sMenu {} {}
  1002.  
  1003. # Tell Alpha what procedures to use to build all menus, submenus.
  1004.  
  1005. menu::buildProc sMenu               S::buildMenu
  1006. menu::buildProc s+Help              S::buildHelpMenu
  1007. menu::buildProc rHelp               S::buildHelpMenu
  1008. menu::buildProc sModeKeywords       S::buildKeywordsMenu
  1009. menu::buildProc markSFileAs…        S::buildMarkMenu
  1010.  
  1011. # First build the main S+ menu.
  1012.  
  1013. proc S::buildMenu {} {
  1014.     
  1015.     global sMenu SmodeVars
  1016.     
  1017.     set app    $SmodeVars(application)
  1018.     set lowApp [string tolower $SmodeVars(application)]
  1019.     
  1020.     set menuList [list                                  \
  1021.       "${lowApp}HomePage"                               \
  1022.       "/S<U<OswitchTo${app}"                            \
  1023.       [list Menu -n ${lowApp}Help          -M S {}]        \
  1024.       "(-"                                              \
  1025.       [list Menu -n sModeKeywords       -M S {}]        \
  1026.       [list Menu -n markSFileAs…        -M S {}]        \
  1027.       "(-"                                              \
  1028.       "/P<U<OprocessFile"                               \
  1029.       "/P<U<O<BprocessSelection"                        \
  1030.       "(-"                                              \
  1031.       "/I<U<OinsertPath"                                \
  1032.       "/b<UcontinueCommand"                             \
  1033.       "(-"                                              \
  1034.       "/N<U<BnextCommand"                               \
  1035.       "/P<U<BprevCommand"                               \
  1036.       "/S<U<BselectCommand"                             \
  1037.       "/I<B<OreformatCommand"                           \
  1038.       ]
  1039.     set submenus [list ${lowApp}Help sModeKeywords markSFileAs… ]
  1040.     return       [list build $menuList S::menuProc $submenus $sMenu]
  1041. }
  1042.  
  1043. # Then build the "S+ Help" submenu.
  1044.  
  1045. proc S::buildHelpMenu {} {
  1046.     
  1047.     global SmodeVars SPrefsInMenu alpha::platform
  1048.     
  1049.     # Determine which key should be used for "Help", with F8 as option.
  1050.     
  1051.     if {!$SmodeVars(noHelpKey)} {
  1052.         set key "/t"
  1053.     } else {
  1054.         set key "/l"
  1055.     } 
  1056.     
  1057.     # Reverse the local, www key bindings depending on the value of the
  1058.     # 'Local Help" variable.
  1059.     
  1060.     if {$SmodeVars(localHelp) == 0} {
  1061.         set menuList [list                  \
  1062.           "${key}<OwwwCommandHelp…"         \
  1063.           "${key}<IlocalCommandHelp…"       \
  1064.           ]
  1065.     } else {
  1066.         set menuList [list                  \
  1067.           "${key}<OlocalCommandHelp…"       \
  1068.           "${key}<IwwwCommandHelp…"         \
  1069.           ]
  1070.     } 
  1071.     lappend menuList "(-"
  1072.     if {$SmodeVars(application) == "S+"} {
  1073.         lappend menuList "r"
  1074.         lappend menuList "!•s+"
  1075.     } else {
  1076.         lappend menuList "!•r"
  1077.         lappend menuList "s+"
  1078.     }
  1079.     lappend menuList "(-"
  1080.     if {${alpha::platform} == "alpha"} {
  1081.         set prefix "!√"
  1082.     } else {
  1083.         set prefix "!•"
  1084.     } 
  1085.     foreach pref $SPrefsInMenu {
  1086.         if {$SmodeVars($pref)} {
  1087.             lappend menuList "${prefix}$pref"
  1088.         } else {
  1089.             lappend menuList "$pref"
  1090.         }
  1091.     }
  1092.     lappend menuList "(-"
  1093.     lappend menuList "setRApplication"
  1094.     lappend menuList "setS+Application"
  1095.     lappend menuList "(-"
  1096.     lappend menuList "${key}<BsModeHelp"
  1097.     
  1098.     return [list build $menuList S::helpProc {}]
  1099. }
  1100.  
  1101. # Then build the "S Mode Keywords" submenu.
  1102.  
  1103. proc S::buildKeywordsMenu {} {
  1104.     
  1105.     set menuList [list \
  1106.       "listKeywords"                    \
  1107.       "checkKeywords"                   \
  1108.       "addNewCommands"                  \
  1109.       "addNewArguments"                 \
  1110.       ]
  1111.     return [list build $menuList S::keywordsProc {}]
  1112. }
  1113.  
  1114. # Then build the "Mark S File As" submenu.
  1115.  
  1116. proc S::buildMarkMenu {} {
  1117.     
  1118.     global SmodeVars alpha::platform
  1119.     
  1120.     set menuList [list                  \
  1121.       "source"                          \
  1122.       "output"                          \
  1123.       "(-"                              \
  1124.       ]
  1125.     if {${alpha::platform} == "alpha"} {
  1126.         set prefix "!√"
  1127.     } else {
  1128.         set prefix "!•"
  1129.     } 
  1130.     if {$SmodeVars(autoMark)} {
  1131.         lappend menuList "${prefix}autoMark"
  1132.     } else {
  1133.         lappend menuList "autoMark"        
  1134.     }
  1135.     return [list build $menuList S::markFileProc {}]
  1136. }
  1137.  
  1138. proc S::rebuildMenu {{menuName "sMenu"} {pref ""}} {
  1139.     menu::buildSome $menuName
  1140. }
  1141.  
  1142. # Dim some menu items when there are no open windows.
  1143. set menuItems {
  1144.     processFile processSelection markSFileAs… 
  1145.     insertPath 
  1146.     nextCommand prevCommand selectCommand
  1147. }
  1148. foreach i $menuItems {
  1149.     hook::register requireOpenWindowsHook [list sMenu $i] 1
  1150. } 
  1151. unset i menuItems 
  1152.  
  1153. # Now we actually build the S+ menu.
  1154.  
  1155. menu::buildSome sMenu
  1156.  
  1157. # ===========================================================================
  1158. # 
  1159. # ◊◊◊◊ S-Plus menu support ◊◊◊◊ #
  1160. # 
  1161.  
  1162. # This is the procedure called for all main menu items.
  1163.  
  1164. proc S::menuProc {menu item} {S::$item}
  1165.  
  1166. # Give a beta message for untested features / menu items.
  1167.  
  1168. proc S::betaMessage {{kill 1}} {
  1169.     
  1170.     beep ; message "Sorry, this feature has not been fully implemented."
  1171.     if {$kill} {return -code return}
  1172. }
  1173.  
  1174. # ===========================================================================
  1175. # 
  1176. # Open the S / R+ home page.
  1177. # 
  1178.  
  1179. proc S::s+HomePage {{app "S+"}} {
  1180.     
  1181.     global SmodeVars
  1182.     
  1183.     if {$app == ""} {set app $SmodeVars(application)} 
  1184.     set lowApp [string tolower $app]
  1185.  
  1186.     url::execute $SmodeVars(${lowApp}HomePage)
  1187. }
  1188.  
  1189. proc S::rHomePage {} {S::s+HomePage "R"}
  1190.  
  1191. # ===========================================================================
  1192. # 
  1193. # Switch to S-Plus or R application
  1194. # 
  1195.  
  1196. proc S::switchToS+ {{app "S+"}} {
  1197.     
  1198.     global SmodeVars
  1199.     
  1200.     if {$app == ""} {set app $SmodeVars(application)}
  1201.  
  1202.     app::launchFore '[S::sig $app]'
  1203. }
  1204.  
  1205. proc S::switchToR {} {S::switchToS+ "R"}
  1206.  
  1207.  
  1208. # ===========================================================================
  1209. # 
  1210. # Return the S+ / R signature.
  1211. # 
  1212.  
  1213. proc S::sig {{app "S+"}} {
  1214.     
  1215.     global SmodeVars tcl_platform
  1216.     
  1217.     if {$app == ""} {set app $SmodeVars(application)}
  1218.  
  1219.     set lowApp [string tolower $app]
  1220.     set capApp [string toupper $app]
  1221.     set pf     $tcl_platform(platform)
  1222.  
  1223.     if {$pf == "macintosh"} {
  1224.         # Make sure that the Macintosh application for the signature exists.
  1225.         if {[catch {nameFromAppl $SmodeVars(${lowApp}Sig)}]} {
  1226.             alertnote "Looking for the $capApp application ..."
  1227.             S::setApplication $lowApp
  1228.         }
  1229.     } elseif {$pf == "windows" || $pf == "unix"} {
  1230.         # Make sure that the Windows application for the signature exists. 
  1231.         # We assume that this will work for unix, too.
  1232.         if {![file exists $SmodeVars(${lowApp}Sig)]} {
  1233.             alertnote "Looking for the $capApp application ..."
  1234.             S::setApplication $lowApp
  1235.         }
  1236.     }
  1237.     return $SmodeVars(${lowApp}Sig)
  1238. }
  1239.  
  1240. # ===========================================================================
  1241. # 
  1242. # Set Application
  1243. # 
  1244. # Prompt the user to locate the local S application.
  1245. # 
  1246.  
  1247. proc S::setApplication {{app ""}} {
  1248.     
  1249.     global mode SmodeVars
  1250.     
  1251.     if {$app == ""} {set app $SmodeVars(application)} 
  1252.  
  1253.     set lowApp [string tolower $app]
  1254.     set capApp [string toupper $app]
  1255.     
  1256.     set newSig ""
  1257.     set newSig [dialog::askFindApp $capApp $SmodeVars(${lowApp}Sig)]
  1258.     
  1259.     if {$newSig != ""} {
  1260.         set SmodeVars(${lowApp}Sig) "$newSig"
  1261.         set oldMode $mode
  1262.         set mode "S"
  1263.         synchroniseModeVar "${lowApp}Sig" $SmodeVars(${lowApp}Sig)
  1264.         set mode $oldMode
  1265.         message "The $capApp signature has been changed to \"$newSig\"."
  1266.     } else {
  1267.         message "Cancelled."
  1268.     }
  1269. }
  1270.  
  1271. # ===========================================================================
  1272. # 
  1273. # ◊◊◊◊ Help ◊◊◊◊ #
  1274. # 
  1275.  
  1276. proc S::helpProc {menu item} {
  1277.     
  1278.     global SmodeVars SPrefsInMenu
  1279.     
  1280.     if {$item == "wwwCommandHelp"} {
  1281.         S::wwwCommandHelp
  1282.     } elseif  {$item == "localCommandHelp"} {
  1283.         S::localCommandHelp
  1284.     } elseif {$item == "r" || $item == "s+"} {
  1285.         S::selectApplication $item
  1286.         S::rebuildMenu
  1287.     } elseif {[lsearch -exact $SPrefsInMenu $item] != -1} {
  1288.         S::flagFlip $item
  1289.         S::rebuildMenu
  1290.     } elseif {$item == "setRApplication"} {
  1291.         S::setApplication "r"
  1292.     } elseif {$item == "setS+Application"} {
  1293.         S::setApplication "s+"
  1294.     } elseif {$item == "sModeHelp"} {
  1295.         package::helpFile "S"
  1296.     } else {
  1297.         S::$item
  1298.     } 
  1299. }
  1300.  
  1301. # Choose between R and S+
  1302.  
  1303. proc S::selectApplication {app} {
  1304.     
  1305.     global mode SmodeVars
  1306.     
  1307.     set app [string toupper $app]
  1308.  
  1309.     set SmodeVars(application) $app
  1310.     set oldMode $mode
  1311.     set mode "S"
  1312.     synchroniseModeVar application $SmodeVars(application)
  1313.     set mode $oldMode
  1314.     message "Default application is now $app."
  1315. }
  1316.  
  1317. # ===========================================================================
  1318. # 
  1319. # ◊◊◊◊ Keywords ◊◊◊◊ #
  1320. # 
  1321.  
  1322. proc S::keywordsProc {menuName item} {
  1323.  
  1324.     global Scmds
  1325.     
  1326.     if {$item == "listKeywords"} {
  1327.         set keywords [listpick -l -p "Current S mode keywords…" $Scmds]
  1328.         foreach keyword $keywords {
  1329.             S::checkKeywords $keyword
  1330.         }
  1331.     } elseif {$item == "addNewCommands" || $item == "addNewArguments"} {
  1332.         set item [string trimleft $item "addNew"]
  1333.         if {$item == "Commands" && [llength [winNames]] && [askyesno \
  1334.           "Would you like to add all of the \"extra\" commands from this window\
  1335.           to the \"Add Commands\" preference?"] == "yes"} {
  1336.             S::addWindowCommands
  1337.         } else {
  1338.             S::addKeywords $item
  1339.         }
  1340.     } else {
  1341.         S::$item
  1342.     } 
  1343. }
  1344.  
  1345. # ===========================================================================
  1346. # 
  1347. # S::addWindowCommands
  1348. # 
  1349. # Add all of the "extra" commands which appear in entries in this window.
  1350. # 
  1351.  
  1352. proc S::addWindowCommands {} {
  1353.     
  1354.     global mode Scmds SmodeVars
  1355.     
  1356.     if {![llength [winNames]]} {
  1357.         message "Cancelled -- no current window!"
  1358.         return
  1359.     } 
  1360.     
  1361.     message "Scanning [win::CurrentTail] for all commands…"
  1362.     
  1363.     set pos  [minPos]
  1364.     set pat1 {[A-Za-z0-9~_.]+[A-Za-z0-9~_.]+[\t ]*\(}
  1365.     set pat2 {\b([-\w_:.]+)\s*\(}
  1366.     while {![catch {search -f 1 -r 1 $pat1 $pos} match]} {
  1367.         set pos  [nextLineStart [lindex $match 1]]
  1368.         set pos1 [lindex $match 0]
  1369.         set pos2 [lindex $match 1]
  1370.         regexp -- $pat2 [getText $pos1 $pos2] match aCommand
  1371.         # Get the line that contains this command.
  1372.         set commandLine [getText [lineStart $pos1] $pos2]
  1373.         # Strip off anything after the first valid comment.
  1374.         regsub -all {\\\#} $commandLine { } commandLine 
  1375.         if {[regexp {\#} $commandLine]} {
  1376.             set firstComment [string first {#} $commandLine]
  1377.             set commandLine [string range $commandLine 0 $firstComment]
  1378.         } 
  1379.         if {[regexp $aCommand $commandLine] && ![lcontains Scmds $aCommand]} {
  1380.             # The command is still in the line, and not recognized.
  1381.             append SmodeVars(addCommands) " $aCommand"
  1382.         } 
  1383.     }
  1384.     set SmodeVars(addCommands) [lsort [lunique $SmodeVars(addCommands)]]
  1385.     set oldMode $mode
  1386.     set mode "S"
  1387.     synchroniseModeVar addCommands $SmodeVars(addCommands)
  1388.     set mode $oldMode
  1389.     if {[llength $SmodeVars(addCommands)]} {
  1390.         S::colorizeS
  1391.         listpick -p "The \"Add Commands\" preference includes:" \
  1392.           $SmodeVars(addCommands)
  1393.         message "Use the \"Mode Prefs --> Preferences\" menu item to edit keyword lists."
  1394.     } else {
  1395.         message "No \"extra\" commands from this window were found."
  1396.     } 
  1397. }
  1398.  
  1399. # ===========================================================================
  1400. # 
  1401. # S::addKeywords
  1402. # 
  1403. # Prompt the user to add keywords for a given category.
  1404. # 
  1405.  
  1406. # Query existing lists of keywords, and add to the mode preferences.
  1407.  
  1408. proc S::addKeywords {category {keywords ""}} {
  1409.     
  1410.     global mode SmodeVars
  1411.     
  1412.     if {$keywords == ""} {
  1413.         set keywords [prompt "Enter new $SmodeVars(application) $category:" ""]
  1414.     }
  1415.     
  1416.     # Check to see if the keyword is already defined.
  1417.     foreach keyword $keywords {
  1418.         set checkStatus [S::checkKeywords $keyword 1 0]
  1419.         if {$checkStatus != 0} {
  1420.             alertnote "Sorry, \"$keyword\" is already defined\
  1421.               in the $checkStatus list."
  1422.             message "Cancelled."
  1423.             return -code return
  1424.         } 
  1425.     }
  1426.     # Keywords are all new, so add them to the appropriate mode preference.
  1427.     append SmodeVars(add$category) " $keywords"
  1428.     set SmodeVars(add$category) [lsort $SmodeVars(add$category)]
  1429.     set oldMode $mode
  1430.     set mode "S"
  1431.     synchroniseModeVar add$category $SmodeVars(add$category)
  1432.     set mode $oldMode
  1433.     S::colorizeS
  1434.     message "\"$keywords\" added to $category preference."
  1435. }
  1436.  
  1437. proc S::checkKeywords {{newKeywordList ""} {quietly 0} {noPrefs 0}} {
  1438.     
  1439.     global SmodeVars
  1440.     
  1441.     global SCommands  SUserCommands SArguments SUserArguments SMassLibrary
  1442.     
  1443.     set type 0
  1444.     if {$newKeywordList == ""} {
  1445.         set quietly 0
  1446.         set newKeywordList [prompt "Enter S mode keywords to be checked:" ""]
  1447.     }
  1448.     # Check to see if the new keyword(s) is already defined.
  1449.     foreach newKeyword $newKeywordList {
  1450.         if {[lsearch -exact $SCommands $newKeyword] != "-1"} {
  1451.             set type SCommands
  1452.         } elseif {[lsearch -exact $SUserCommands $newKeyword] != "-1"} {
  1453.             set type SUserCommands
  1454.         } elseif {[lsearch -exact $SArguments $newKeyword] != "-1"} {
  1455.             set type SArguments
  1456.         } elseif {[lsearch -exact $SUserArguments $newKeyword] != "-1"} {
  1457.             set type SUserArguments
  1458.         } elseif {[lsearch -exact $SMassLibrary $newKeyword] != "-1"} {
  1459.             set type SMassLibrary
  1460.         } elseif {!$noPrefs && \
  1461.           [lsearch -exact $SmodeVars(addCommands) $newKeyword] != "-1"} {
  1462.             set type SmodeVars(addCommands)
  1463.         } elseif {!$noPrefs && \
  1464.           [lsearch -exact $SmodeVars(addArguments) $newKeyword] != "-1"} {
  1465.             set type SmodeVars(addArguments)
  1466.         }
  1467.         if {$quietly} {
  1468.             # When this is called from other code, it should only contain
  1469.             # one keyword to be checked, and we'll return it's type.
  1470.             return "$type"
  1471.         } elseif {!$quietly && $type == 0} {
  1472.             alertnote "\"$newKeyword\" is not currently defined\
  1473.               as a S mode keyword"
  1474.         } elseif {$type != 0} {
  1475.             # This will work for any other value for "quietly", such as 2
  1476.             alertnote "\"$newKeyword\" is currently defined as a keyword\
  1477.               in the \"$type\" list."
  1478.         } 
  1479.         set type 0
  1480.     }
  1481. }
  1482.  
  1483. # ===========================================================================
  1484. # 
  1485. # ◊◊◊◊ Processing ◊◊◊◊ #
  1486. # 
  1487.  
  1488. # ===========================================================================
  1489. # 
  1490. # Process File
  1491. # 
  1492. # Send entire file to S+ / R for processing, adding carriage return at end
  1493. # of file if necessary.
  1494. # 
  1495. # Optional "f" argument allows this to be called by other code, or to be 
  1496. # sent via a Tcl shell window.
  1497. # 
  1498.  
  1499. proc S::processFile {{f ""} {app ""}} {
  1500.     
  1501.     global SmodeVars
  1502.     
  1503.     if {$f != ""} {file::openAny $f}
  1504.     set f [win::Current]
  1505.  
  1506.     if {$app == ""} {set app $SmodeVars(application)}
  1507.  
  1508.     set lowApp [string tolower $app]
  1509.     set capApp [string toupper $app]
  1510.  
  1511.     set dirtyWindow [winDirty]
  1512.     set dontSave 0
  1513.     if {$dirtyWindow && [askyesno \
  1514.       "Do you want to save the file before sending it to $capApp?"] == "yes"} {
  1515.         save
  1516.     } else {
  1517.         set dontSave 1
  1518.     } 
  1519.     if {!$dontSave && [lookAt [pos::math [maxPos] - 1]] != "\r"} {
  1520.         set pos [getPos]
  1521.         goto [maxPos]
  1522.         insertText "\r"
  1523.         goto $pos
  1524.         alertnote "Carriage return added to end of file."
  1525.         save
  1526.     }
  1527.  
  1528.     app::launchBack '[S::sig $capApp]'
  1529.     sendOpenEvent noReply '[S::sig $capApp]' $f
  1530.     switchTo '[S::sig $capApp]'
  1531. }
  1532.  
  1533. # ===========================================================================
  1534. # 
  1535. # Process Selection
  1536. # 
  1537. # Procedure to implement transfer of selected lines to S+ / R for processing.
  1538. # 
  1539.  
  1540. proc S::processSelection {{selection ""} {app ""}} {
  1541.     
  1542.     global PREFS SmodeVars
  1543.     
  1544.     if {$app == ""} {set app $SmodeVars(application)}
  1545.  
  1546.     set lowApp [string tolower $app]
  1547.     set capApp [string toupper $app]
  1548.  
  1549.     if {$selection == ""} {
  1550.         if {![isSelection]} {
  1551.             message "No selection -- cancelled."
  1552.             return
  1553.         } else {
  1554.             set selection [getSelect]
  1555.         } 
  1556.     }
  1557.     file::ensureDirExists [file join $PREFS S-tmp]
  1558.     set newFile [file join $PREFS S-tmp temp-S.s]
  1559.     file::writeAll $newFile $selection 1
  1560.  
  1561.     app::launchBack '[S::sig $capApp]'
  1562.     sendOpenEvent noReply '[S::sig $capApp]' $newFile
  1563.     switchTo '[S::sig $capApp]'
  1564. }
  1565.  
  1566. proc S::quitHook {} {temp::cleanup S-tmp}
  1567.  
  1568. # ===========================================================================
  1569. # 
  1570. # ◊◊◊◊ Marks ◊◊◊◊ #
  1571. # 
  1572.  
  1573. proc S::markFileProc {menu item} {
  1574.  
  1575.     if {$item == "source"} {
  1576.         S::MarkFile {.s}
  1577.     } elseif {$item == "output"} {
  1578.         # doesn't really matter what we put for the mark file "type" here,
  1579.         # since output is the default if other "if ..." cases aren't met.
  1580.         S::MarkFile {.out}
  1581.     } elseif {$item == "autoMark"} {
  1582.         S::flagFlip autoMark
  1583.         S::rebuildMenu markS+FileAs…
  1584.         S::rebuildMenu markRFileAs…
  1585.     }
  1586. }
  1587.  
  1588. # ===========================================================================
  1589. # 
  1590. # ◊◊◊◊ Insertions ◊◊◊◊ #
  1591. # 
  1592.  
  1593. proc S::insertPath {} {
  1594.     
  1595.     global file::separator
  1596.     
  1597.     set path ""
  1598.     set t    ""
  1599.     append t "\"${file::separator}"
  1600.     set path [getfile "Choose path of target file:"]
  1601.     if {$path != ""} {
  1602.         append t $path
  1603.         append t "\""
  1604.         insertText $t
  1605.     }
  1606. }
  1607.  
  1608. # ===========================================================================
  1609. # 
  1610. # ◊◊◊◊ Navigation ◊◊◊◊ #
  1611. # 
  1612.  
  1613. # Next/Prev command can simply return the position of the next command
  1614. # (quietly == 1), move the cursor to the next command (placing the cursor
  1615. # at the top of the window if toTop == 1), extend the current selection to
  1616. # the end of the this command, or (if the current command is already
  1617. # highlighted in its entirety) extend the current selection to the end of
  1618. # the next command.
  1619. # 
  1620.  
  1621. proc S::nextCommand {{quietly 0} {toTop 0}} {
  1622.     
  1623.     if {[pos::compare [selEnd] == [maxPos]]} {
  1624.         set pos [maxPos]
  1625.     } else {
  1626.         set pos [pos::math [selEnd] + 1]
  1627.     } 
  1628.     set pat {^[^\r\n\t \#\}\)]}
  1629.     if {![catch {search -f 1 -r 1 $pat $pos} match]} {
  1630.         set pos [lineStart [lindex $match 1]]
  1631.     } else {
  1632.         set pos [maxPos]
  1633.     }
  1634.     if {$quietly} {
  1635.         return $pos
  1636.     } elseif {[isSelection]} {
  1637.         set limit1 [lindex [S::getCommand [selEnd]] 1]
  1638.         set limit2 [lindex [S::getCommand $pos    ] 1]
  1639.         if {$limit2 == "-1"} {set limit2 [maxPos]}
  1640.         if {$limit1 == "-1"} {set limit1 $limit2}
  1641.         if {[pos::compare [selEnd] < $limit1]} {
  1642.             select [getPos] $limit1
  1643.         } else {
  1644.             select [getPos] $limit2
  1645.         } 
  1646.     } elseif {$pos == [maxPos]} {
  1647.         message "No further commands in the file."
  1648.         return
  1649.     } else {
  1650.         goto $pos
  1651.         message [getText $pos [nextLineStart $pos]]
  1652.     } 
  1653.     if {$toTop} {insertToTop}
  1654. }
  1655.  
  1656. proc S::prevCommand {{quietly 0} {toTop 0}} {
  1657.     
  1658.     if {[pos::compare [getPos] == [minPos]]} {
  1659.         set pos [minPos]
  1660.     } else {
  1661.         set pos [pos::math [getPos] - 1]
  1662.     } 
  1663.     set pat {^[^\r\n\t \#\}\)]}
  1664.     if {![catch {search -f 0 -r 1 $pat $pos} match]} {
  1665.         set pos [lineStart [lindex $match 0]]
  1666.     } else {
  1667.         set pos [minPos]
  1668.     }
  1669.     if {$quietly} {
  1670.         return $pos
  1671.     } elseif {[isSelection]} {
  1672.         # Going backwards is actually easier with selections.
  1673.         select $pos [selEnd]
  1674.     } elseif {$pos == [minPos]} {
  1675.         message "No further commands in the file."
  1676.         return
  1677.     } else {
  1678.         goto $pos
  1679.         message [getText $pos [nextLineStart $pos]]
  1680.     } 
  1681.     if {$toTop} {insertToTop}
  1682.     return $pos
  1683. }
  1684.  
  1685. proc S::searchFunc {direction} {
  1686.     
  1687.     if {$direction} {
  1688.         S::nextCommand
  1689.     } else {
  1690.         S::prevCommand
  1691.     }
  1692. }
  1693.  
  1694. proc S::selectCommand {} {
  1695.     
  1696.     set pos    [getPos]
  1697.     set limits [S::getCommand $pos]
  1698.     set posBeg [lindex $limits 0]
  1699.     set posEnd [lindex $limits 1]
  1700.     
  1701.     if {$posBeg != "-1" && $posEnd != "-1" && \
  1702.       [pos::compare $pos >= $posBeg] && [pos::compare $pos <= $posEnd]} {
  1703.         select $posBeg $posEnd
  1704.     } else {
  1705.         message "The cursor is not within a command."
  1706.         error "The cursor is not within a command."
  1707.     } 
  1708. }
  1709.  
  1710. proc S::copyCommand {{quietly 0}} {
  1711.     
  1712.     set pos [getPos]
  1713.     if {[set posBeg [lindex [S::getCommand $pos] 0]] != "-1"} {
  1714.         goto $posBeg
  1715.         forwardWord
  1716.         set posEnd [getPos]
  1717.         if {!$quietly} {
  1718.             select $posBeg $posEnd
  1719.             copy
  1720.             message "\"[getText $posBeg $posEnd]\" copied to clipboard."
  1721.         } 
  1722.         goto $pos
  1723.         return [getText $posBeg $posEnd]
  1724.     } elseif {!$quietly} {
  1725.         message "The cursor is not within a command."
  1726.     }
  1727.     return ""
  1728. }
  1729.  
  1730. proc S::reformatCommand {} {
  1731.     
  1732.     if {![isSelection]} {S::selectCommand} 
  1733.     message "Reformatting …"
  1734.     ::indentRegion
  1735.     goto [pos::math [getPos] -1]
  1736.     goto [S::nextCommand 1]
  1737.     message "Reformatted."
  1738. }
  1739.  
  1740. proc S::getCommand {pos} {
  1741.     
  1742.     set pos1 [pos::math [nextLineStart $pos] - 1]
  1743.     set pat {^[^\r\n\t \}\)]}
  1744.     set posBeg "-1"
  1745.     set posEnd "-1"
  1746.     if {![catch {search -f 0 -r 1 $pat $pos1} match]} {
  1747.         set posBeg [lindex $match 0]
  1748.         set pos2   [nextLineStart $posBeg]
  1749.         if {![catch {search -f 1 -r 1 $pat $pos2} match]} {
  1750.             set posEnd [lindex $match 0]
  1751.         } else {
  1752.             set posEnd [maxPos]
  1753.         } 
  1754.         # Now back up to remove empty or commented lines.
  1755.         set posEndPrev [pos::math $posEnd - 1]
  1756.         set prevLine [getText [lineStart $posEndPrev] $posEndPrev]
  1757.         while {[regexp {^[\t ]*$} $prevLine]} {
  1758.             set posEnd [lineStart $posEndPrev]
  1759.             set posEndPrev [pos::math $posEnd - 1]
  1760.             set prevLine [getText [lineStart $posEndPrev] $posEndPrev]
  1761.         }
  1762.     } 
  1763.     return [list $posBeg $posEnd]
  1764. }
  1765.  
  1766. # ===========================================================================
  1767. # 
  1768. # ◊◊◊◊ --------------------- ◊◊◊◊ #
  1769. # 
  1770. # ◊◊◊◊ version history ◊◊◊◊ #
  1771. # 
  1772. #  modified by  vers#  reason
  1773. #  -------- --- ------ -----------
  1774. #  01/28/20 cbu 1.0.1  First created S mode, based upon other modes found 
  1775. #                        in Alpha's distribution.   Commands are based on 
  1776. #                        release number 3.3, taken from the "common commands" 
  1777. #                        as listed in Venable and Ripley's "Modern Applied 
  1778. #                        Statistics with S-PLUS", second edition.
  1779. #  03/02/20 cbu 1.0.2  Minor modifications to comment handling.
  1780. #  03/20/00 cbu 1.0.3  Minor update of keywords dictionaries.
  1781. #                      Removed markFile and parseFuncs procs, because they're 
  1782. #                        not stable or properly worked out.
  1783. #  04/01/00 cbu 1.0.4  Fixed a little bug with "comment box".
  1784. #                      Added new preferences to allow the user to optionally 
  1785. #                        use $ as a Magic Character, and to enter additional 
  1786. #                        commands and options.  
  1787. #                      Removed the "Either/Ors" category, put them into arguments.
  1788. #                      Added the C++ MarkFile and parseFuncs procs.
  1789. #                      Added "Update Colors" proc to avoid need for a restart
  1790. #  04/08/00 cbu 1.0.5  Unset obsolete preferences from earlier versions.
  1791. #                      Added "Continue Comment" and "Electric Return Over-ride".
  1792. #                      Renamed "Update Colors" to "Update Preferences".
  1793. #                      Added the tcl indentation routines.
  1794. #  04/16/00 cbu 1.1    Renamed to sMode.tcl
  1795. #                      Wrote my own "Mark File" proc, replaced the C++ MarkFile.
  1796. #                      Removed indentation routines, at least for now.
  1797. #  06/22/00 cbu 1.2    "Mark File" now recognizes headings as well as commands.
  1798. #                      Completions, Completions Tutorial added.
  1799. #                      "Reload Completions", referenced by "Update Preferences".
  1800. #                      Better support for user defined keywords.
  1801. #                      Removed "Continue Comment", now global in Alpha 7.4.
  1802. #                      Added command double-click for on-line help.
  1803. #                      <shift, control>-<command> double-click syntax info.
  1804. #                        (Foundations, at least.  Ongoing project.)
  1805. #  08/07/00 cbu 1.2.1  DblClick now looks for variable (etc) definitions
  1806. #                        in current file.
  1807. #                      Added message if no matching ")".
  1808. #                      Mark File can mark a frequencies file.
  1809. #                      Beta-version of an S-Plus menu, based on the Stata menu.
  1810. #                        No Macintosh versions of S-Plus or R limit its
  1811. #                        functionality ...
  1812. #                      Added "s+Sig" preference to allow user to find
  1813. #                        local application if necessary, in case S+/R is ever
  1814. #                        ported to the Macintosh.
  1815. #                      Added S::sig which returns S-Plus signature.
  1816. #  08/28/00 cbu 1.2.2  Added some of the flag preferences to "S+/R Help" menu.
  1817. #                      Added "flagFlip" to update preference bullets in menu.
  1818. #                      Added "application" preference, used in menu.
  1819. #                      Added "rSig" preference.
  1820. #                      Added a "noHelpKey" preference, which switches the
  1821. #                        "help" key binding to F8.
  1822. #                      Added "Add New Commands / Arguments" to "S+/R Help" menu.
  1823. #                      Added "Set S+/R Application to "S+/R Help" menu.
  1824. #                      Starting to differentiate code based on platform.
  1825. #                      Including a "beta message" for untested menu items.
  1826. #  11/05/00 cbu 1.3    Added "next/prevCommand", "selectCommand", and
  1827. #                        "copyCommand" procs to menu.
  1828. #                      Added "S::indentLine".
  1829. #                      Added "S::reformatCommand" to menu.
  1830. #                      Added "S::continueCommand" to over-ride indents. 
  1831. #                      "S::reloadCompletions" is now obsolete.
  1832. #                      "S::updatePreferences" is now obsolete.
  1833. #                      "S::colorizeS" now takes care of setting all 
  1834. #                        keyword lists, including Scmds.
  1835. #                      Cleaned up completion procs.  This file never has to be
  1836. #                        reloaded.  (Similar cleaning up for "S::DblClick").
  1837. #  11/16/00 cbu 2.0    New url prefs handling requires 7.4b21
  1838. #                      Added "Home Page" pref, menu item.
  1839. #                      Removed  hook::register requireOpenWindowsHook from
  1840. #                        mode declaration, put it after menu build.
  1841. #  12/19/00 cbu 2.1    The menu proc "Add Commands" now includes an option
  1842. #                        to grab all of the "extra" command from the current
  1843. #                        window, using S::addWindowCommands.
  1844. #                      Added "Keywords" submenu, "List Keywords" menu item.
  1845. #                      Big cleanup of ::sig, ::setApplication, processing ...
  1846. #  01/25/01 cbu 2.1.1  Bug fix for S::processSelection/File.
  1847. #                      Bug fix for comment characters.
  1848. # 
  1849.  
  1850. # ===========================================================================
  1851. # 
  1852. # .
  1853.  
  1854.